Commit 5951f378 authored by Julien Fastré's avatar Julien Fastré
Browse files

initial commit

parents
[out:json][timeout:25];
{{geocodeArea:"Digne-Les-Bains"}}->.digne;
(
node["amenity"="bicycle_parking"](area.digne);
way["amenity"="bicycle_parking"](area.digne);
)->.parkings;
(
node(around.parkings:50)["amenity"];
way(around.parkings:50)["amenity"];
);
out body;
>;
out skel qt;
[out:json][timeout:25];
//trouver l'area "Digne-Les-Bains"
{{geocodeArea:"Digne-Les-Bains"}}->.digne;
//trouver les amenities;
(
way["amenity"](area.digne);
node["amenity"](area.digne);
)->.amenities;
(
way.amenities["wheelchair"="yes"];
node.amenities["wheelchair"="yes"];
)->.accessibles;
.accessibles out body;
.accessibles>;
out skel qt;
[out:json][timeout:25];
//trouver l'area "Digne-Les-Bains"
{{geocodeArea:"Digne-Les-Bains"}}->.digne;
//trouver les banques
(
way[amenity=bank](area.digne);
node[amenity=bank](area.digne);
)->.banks;
//filtrer sur atm
(
way.banks[atm=yes];
node.banks[atm=yes];
)->.banks_with_atm;
.banks_with_atm out body;
.banks_with_atm>; out skel qt;
[out:json][timeout:25];
//trouver l'area "Liège"
{{geocodeArea:"Liège,Belgium"}}->.liege;
//trouver les chemins
(
way["highway"](area.liege);
)->.highways;
//filtrer sur aménagements
(
// rues qui ont une pistes cyclable
way.highways["cycleway"];
// rues dédiées au vélo
way.highways["highway"="cycleway"];
// rues avec pistes cyclable à gauche ou à droite
way.highways["cycleway:left"];
way.highways["cycleway:right"];
// sens uniques limités
way.highways["oneway:bicycle"="no"];
way.highways["bicycle:oneway"="no"];
)->.bike_friendly;
.bike_friendly out body;
.bike_friendly>; out skel qt;
[out:json][timeout:25];
//trouver l'area "Alpes-de-haute-Provence"
{{geocodeArea:"Alpes-de-Haute-Provence"}}->.dept;
//filtrer les routes principales
(
way["highway"="primary"](area.dept);
way["highway"="secondary"](area.dept);
)->.routes;
//filtrer les routes dont la ref. commence par D
way.routes["ref"~"^D"];
out body;
>;
out skel qt;
[out:json][timeout:25];
//trouver l'area "Alpes-de-haute-Provence"
{{geocodeArea:"Alpes-de-Haute-Provence"}}->.dept;
//filtrer les routes principales
way["highway"="primary"](area.dept)->.routes;
//filtrer les routes dont la ref. commence par D
way.routes["ref"~"^D"];
out body;
>;
out skel qt;
[out:json][timeout:25];
{{geocodeArea:"Digne-Les-Bains"}}->.digne;
rel[type=route](area.digne);
rel._[route=bus];
out tags;
way(r._);
out skel;
>;
out skel qt 99;
[out:json][timeout:60];
//trouver l'area "Digne-Les-Bains"
{{geocodeArea:"Liège,Belgium"}}->.digne;
//trouver les chemins
(
way["highway"](area.digne);
)->.highways;
//filtrer sur aménagements
(
// rues qui ont une pistes cyclable
way.highways["cycleway"];
// rues dédiées au vélo
way.highways["highway"="cycleway"];
// rues avec pistes cyclable à gauche ou à droite
way.highways["cycleway:left"];
way.highways["cycleway:right"];
// sens uniques limités
way.highways["oneway:bicycle"="no"];
way.highways["bicycle:oneway"="no"];
)->.bike_friendly;
node(w.bike_friendly)->.points;
way(bn.points)->.all_ways_touched_by_bike_friendly;
(way.all_ways_touched_by_bike_friendly - way.bike_friendly)->.way_crossing_bike_friendly;
.way_crossing_bike_friendly out skel qt;
.way_crossing_bike_friendly>;
out skel qt ;
Atelier de découverte Overpass API
===================================
Cet atelier a été dispensé le 10 juillet 2015 à [UDOS](http://www.udos.fr) par Julien Fastré.
Il couvre les informations suivantes :
- découverte du langage QL, utilisé par [Overpass API](http://overpass-api.de);
- architecture overpass api/ [overpass turbo](http://overpass-turbo.eu) ;
- rappel du modèle de donnée [d'OpenStreetMap](http://openstreetmap.org) et correspondance avec le modèle utilisé par Overpass api.
L'atelier introduit les concepts du langage, et propose ensuite des requêtes qui les mettent en pratique. En fonction du niveau des utilisateurs, il est conseillé au formateur de préparer les requêtes proposées en établissant le pseudo-code avec eux, et/ou en leur proposant d'écrire les requêtes par petits groupes.
Licence
--------
Cet atelier est disponible sous licence CC-BY-SA 4.0 par [Champs Libres Cooperative SCRLFS](http://champs-libres.coop).
Markdown is supported
0% or .
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment